ArchiCAD 次世代足場GDLの作成~布材~

布材完成イメージ

!----------------------------------
!布材設定
!----------------------------------
ledger_R = 43/(2*t)		!布材半径
ledger_D = 78/t		!支柱芯からの距離

values "ZZYZX", 1.9	!支柱サイズ

values "A", 1.829, 1.524, 1.219, 0.914, 0.610	!桁行方向サイズ
values "B", 1.219, 0.914, 0.610		!梁間方向サイズ

"梁間方向布材":
	material ledger_mat
	hotspot 0, 0, 0
	revolve 2, 360, 1+2+4+8+16+32,
		ledger_D, ledger_R, 0,
		B - ledger_D, ledger_R, 0

	gosub "布材爪"
	add B, 0, 0
	mulx -1
	gosub "布材爪"
	del 2
return

"布材爪":
	rotx 90
	cutpolya 6, 1, 0,
		0, 0.005, 15,
		0.055, 0.005, 15,
		0.06, 0.001, 1015,
		0.06, -0.001, 15,
		0.055, -0.005, 1015,
		0, -0.005, 15
	del 1
	
	revolve 6, 360, 1+2+4+8+16+32,
		0.025, 0.018, 0, 
		0.027, 0.020, 0,
		0.042, 0.020, 0,
		0.071, 0.020, 0,
		0.076, 0.018, 0,
		ledger_D, 0.018, 0
	cutend

	!楔
	ruledsegmented 4, 1+2+4+16,
		0.03, -0.002, 0.03, 0,
		0.04, -0.002, 0.03, 0,
		0.035, -0.002, -0.03, 1000,
		0.03, -0.002, -0.03, 0,
		0.03, 0.002, 0.03,
		0.04, 0.002, 0.03,
		0.035, 0.002, -0.03,
		0.03, 0.002, -0.03
return

revolveコマンド

今回は、筒状の形状を作るために revolve コマンドを使ってみました。このコマンドは、指定した断面形状を軸の周りに回転させることで3D形状を生成します。陶芸でろくろを使って壺などを作るときのイメージを持つとわかりやすいと思います。

revolveコマンドイメージ

ruledsegmentedコマンド

ruledsegmented コマンドは、頂点数が同じ2つの断面形状を指定し、それらを結ぶ面を生成するために使用されます。今回は、このコマンドを楔の部分に使用しています。

ruledsegmentedコマンドイメージ

パラメータ"A"、"B"、"ZZYZX"

情報ボックスによるパラメータ変更

material pillar_mat

gosub "支柱"
add 0, B, 0
gosub "支柱"
del 1

material ledger_mat
add 0, 0, 1.865
rotz 90
gosub "梁間方向布材"
del 2

end