ArchiCAD 次世代足場GDLの作成~階段~

階段イメージ

新規パラメータの追加

新規パラメータ

上の画像のように、dis_stairs というブール値のパラメータを新規追加しました。このパラメータをオン・オフすることで、階段の非表示をコントロールできるようにします。

ささらと踏面の作成

!----------------------------------
!階段
!----------------------------------
stairs_D = 100/t		!支柱芯からの距離
stairs_num = 8			!段数
riser_H = 1.9/stairs_num	!蹴込み高さ
tread_W = 1.829/stairs_num	!踏面幅

!----------------------------------
!階段
!----------------------------------

"階段":
	add 0.04, 0.1, 0.05
	roty 90 - atn(1.9 / 1.829)
	gosub "ささら"
	del 2

	add 0.04, 0.55, 0.05
	roty 90 - atn(1.9 / 1.829)
	gosub "ささら"
	del 2

	for i = 1 to stairs_num-1
		add tread_W*i - 0.05, 0.12, riser_H*i
		brick 0.2, 0.43, 0.02
		del 1
	next i
return

"ささら":
	brick 0.06, 0.02, sqr((1.829 - stairs_D*2)**2 + 1.9**2)
return

ささらの作成

踏面の作成

階段がある時の場合分け

unid = 3000

material pillar_mat
gosub "支柱"
add 0, B, 0
gosub "支柱"
del 1

material ledger_mat
add 0, 0, 1.865
rotz 90
gosub "梁間方向布材"
del 2

material anti_mat


if dis_stairs & A > 1.8 then
	if b > 0.9 & b < 1.3 then
		addy B
		muly -1
		gosub "階段"
		del 2

		if b < 1.2 then
			add 0, 0.210, 1.865
			gosub "240アンチ"
			del 1
		else
			add 0, 0.362, 1.865
			gosub "490アンチ"
			del 1
		endif
	else
		gosub "アンチ"
	endif
else
	gosub "アンチ"
endif

addz -0.035
gosub "ブレース"
addy B
gosub "ブレース"
del 2

end

完成

足場GDLの階段