多角形GDLに機能を追加してみる②

角度の表示

角度の計算

for i=1 to vertices
	x[i]=x[i]
	y[i]=y[i]	
next i

for i=1 to vertices
	if i=vertices then
		after=1
	else
		after=i+1
	endif

	 length[i]=sqr((x[after]-x[i])**2+(y[after]-y[i])**2)
next i

parameters \
x=x,
y=y,
length=length

for i=1 to vertices
	if i=1 then
		i1=vertices
	else
		i1=i-1
	endif

	if i=vertices then
		i2=1
	else
		i2=i+1
	endif

	!ベクトルの成分
	ax=x[i2]-x[i]
	ay=y[i2]-y[i]
	bx=x[i1]-x[i]
	by=y[i1]-y[i]

	!内積から角度を求める
	t=acs((ax*bx+ay*by)/(sqr(ax**2+ay**2)*sqr(bx**2+by**2)))

	!外積から向きを求める
	if ax*by-ay*bx >= 0 then
		angle[i]=t
	else
		angle[i]=360 - t
	endif
next i

parameters angle=angle

DEFINE STYLE "test" "New York", 2, 5, 0
SET STYLE "test"

unID=1

for i=1 to vertices
	hotspot2 0	 , y[i], unID, x[i], 1+128	:unID=unID+1
	hotspot2 x[i], y[i], unID, x[i], 2		:unID=unID+1
	hotspot2 -1	 , y[i], unID, x[i], 3		:unID=unID+1

	hotspot2 x[i], 0   , unID, y[i], 1+128	:unID=unID+1
	hotspot2 x[i], y[i], unID, y[i], 2		:unID=unID+1
	hotspot2 x[i], -1  , unID, y[i], 3		:unID=unID+1

	if i=vertices then
		after=1
	else
		after=i+1
	endif

	if sqr((x[after]-x[i])**2+(y[after]-y[i])**2)>0 then
		line2 x[i], y[i], x[after], y[after]
		hotline2 x[i], y[i], x[after], y[after], unID	:unID=unID+1

		!長さ表示
		text2 (x[after]-x[i])/2+x[i], (y[after]-y[i])/2+y[i], str(length[i]*1000, 5,0)

		!角度表示
		text2 x[i], y[i], str(angle[i], 3, 2)
	endif
next i

動きの確認