ArchiCAD MVOで鉄筋情報をコントロールしてみる

鉄筋情報MVOの作成

パラメータリスト

まずはマスタースクリプトで、ボタンを押して配列データを増減させるための機能や、UIで入力した時にデータが更新されるような処理を実装していきます。GLOB_UI_BUTTON_IDという変数が使われていますが、これはUIで押されたボタンのIDを返すグローバル変数です。ボタンのIDは後述するUIスクリプトで任意に定義することができます。この機能を使うことで、「ボタンを押したらリストを増やす」のようなことが可能となっています。

またupdate関連の関数をいくつか定義していますが、これはUIで入力されたデータを配列パラメータに反映するための処理です。上の画像で言うと、赤線部分で入力したものを青線部分のパラメータに格納する処理をここで実装しています。

マスタースクリプト

!リスト数一時格納
list_num=list_num


!リスト数増やす
if GLOB_UI_BUTTON_ID=1 then
	list_num=list_num+1
	gosub "list_update"
	parameters select_index=list_num, 
			   input_symbol=symbol[select_index],
			   input_top_C=top1_num[select_index],
			   input_stp=stp_pitch[select_index]
endif

!リスト数減らす
if GLOB_UI_BUTTON_ID=2 & list_num>1 then
	list_num=list_num-1
	gosub "list_update"
	parameters select_index=list_num, 
			   input_symbol=symbol[select_index],
			   input_top_C=top1_num[select_index],
			   input_stp=stp_pitch[select_index]
endif

!ALL DELETE
if GLOB_UI_BUTTON_ID=99 then
	list_num=1
	gosub "list_update"
	parameters select_index=list_num, 
			   input_symbol=symbol[select_index],
			   input_top_C=top1_num[select_index],
			   input_stp=stp_pitch[select_index]
endif

parameters list_num=vardim1(top1_num)

!変更
gosub "symbol_update"
gosub "top_update"
gosub "stp_update"
gosub "select_index"


goto "masterEND"

!===============リスト数アップデート===================
"list_update":
!====================================================
	DIM _symbol[],
		_top1_num[],
		_stp_pitch[]

	for i=1 to list_num
		_symbol[i]=symbol[i]
		_top1_num[i]=top1_num[i]
		_stp_pitch[i]=stp_pitch[i]
	next i

	parameters  symbol=_symbol,
				top1_num=_top1_num,
				stp_pitch=_stp_pitch
				
return

!=====================入力反映========================
"symbol_update":
!====================================================
	if glob_modpar_name="input_symbol" then
		symbol[select_index]=input_symbol
		parameters symbol=symbol
	endif
return

!=====================入力反映========================
"top_update":
!====================================================
	if glob_modpar_name="input_top_C" then
		top1_num[select_index]=input_top_C
		parameters top1_num=top1_num
	endif
return

!=====================入力反映========================
"stp_update":
!====================================================
	if glob_modpar_name="input_stp" then
		stp_pitch[select_index]=input_stp
		parameters stp_pitch=stp_pitch
	endif
return

!=====================入力反映========================
"select_index":
!====================================================
	if glob_modpar_name="select_index" then
		input_symbol=symbol[select_index]
		input_top_C=top1_num[select_index]
		input_stp=stp_pitch[select_index]
		parameters input_symbol=input_symbol,
			       input_top_C=input_top_C,
				   input_stp=input_stp
	endif
return


"masterEND":

values "list_num" range[1,]
values "top1_num" range[1,]
values "stp_pitch" range[0.05,]

for i=1 to list_num
	put i
next i

values "select_index", get(nsp)

UIイメージ

ui_dialog "bim-arekore"
gosub "鉄筋データ"

end

!============================================
"鉄筋データ":
!============================================
	ui_page 1, -1, "入力"

	ui_outfield "id", 10, 10, 30, 20
	ui_infield "select_index" , 45, 8, 50, 20

	ui_outfield "符号", 10, 50, 30, 20
	ui_infield "input_symbol" , 45, 48, 50, 20

	ui_outfield "本数", 10, 80, 30, 20
	ui_infield "input_top_C" , 45, 78, 50, 20

	ui_outfield "stp", 10, 110, 30, 20
	ui_infield "input_stp" , 45, 108, 50, 20
	
	!ui_infield "symbol" , 40, 40, 50, 20
	

	
	!リスト数増減
	ui_button ui_function, "+", 25, 190, 25, 20, 1
	ui_button ui_function, "-", 55, 190, 25, 20, 2

	ui_button ui_function, "all del", 25, 220, 55, 20, 99
return